Excel Count函数的使用方法，包含与If、Find与Frequency组合实现统计满足指定条件、重复值与唯一值个数实例

　　在 Excel 中，Count函数用于统计数值与日期个数，它至少要包含一个值最多只能有 255 个值。Count函数不统计空格与不能转为数字的文本，如果要统计它们需要用CountA函数。

　　Count函数除单独使用外，还常与 If、Find 与 Frequency 函数组合使用；Count + If 组合实现统计满足指定条件的个数，Count + Find 组合实现统计重复值的个数，Count + Frequency 组合实现统计不包括重复值（即唯一值）的个数。

　　一、Excel Count函数的语法

　　1、表达式：COUNT(Value1, [Value2], ...)

　　中文表达式：Count(值1, [值2], ...)

　　2、说明：

　　A、Value 可以是数字、数组或单元格区域的引用，至少要包含一个 Value，最多只能有 255 个。

　　B、如果 Value 为数字、日期、能转为数值的文本（如"2"），都被计入统计个数。如果 Value 为逻辑值（True 或 False），若 Value 直接写在Count函数中，则被计入统计个数；若 Value 为单元格或数组中的值，则不被计入统计个数。如果要统计有文本、逻辑值、空值（如公式返回的空值""）和错误值的单元格，可以用CountA函数。

　　C、如果 Value 为空格、不能转为数值的文本（如"二"）或错误值，将不被计入统计个数。

　　二、Excel Count函数的使用方法及实例

　　（一）引用区域为单元格的实例

　　假如要统计 C 列的数字个数。双击 C8 单元格，输入公式 =count(c2:c7)，按回车，返回统计结果 6；操作过程步骤，如图1所示：

图1

　　（二）统计数组中数值的实例

　　1、双击 A1 单元格，把公式 =COUNT(6,{3,8,10,5,2}) 复制到 A1，按回车，返回统计结果 6；操作过程步骤，如图2所示：

图2

　　2、公式 =COUNT(6,{3,8,10,5,2}) 的参数为一个数字和一个数组，统计结果为 6，说明独立数字和数组都计入统计。

　　（三）Value 为数字、日期或能转为数值的文本实例

　　1、双击 B1 单元格，输入公式 =COUNT(A1:A3)，按回车，返回统计结果 2，把 A3 中 "16" 删除，B1 中的值仍为 2；双击 B2，把公式=COUNT(38,2018/12/24,"16") 复制 B2，按回车，返回统计结果 3；操作过程步骤，如图3所示：

图3

　　2、三个相同的值，一个公式统计结果为 2，另一个公式统计结果为 3，它们之间的区别是一个值在单元格中，另一个值在数组中，并且从操作可以看出，单元格中的 "16" 没有被统计，而数组中的 "16" 被统计了；这就说明数组中的 "16" 是能转为数值的文本，而单元格中的"16" 不能，单元格中的能转为数值的文本是指单元格格式为文本型。

　　（四）Value 含有逻辑值 True 和 False 的实例

　　1、双击 B1 单元格，输入公式 =COUNT(A1:A3)，按回车，返回统计结果 1；双击 B2，把公式 =COUNT(38,TRUE,FALSE) 复制到 B2，按回车，返回统计结果 3；操作过程步骤，如图4所示：

图4

　　2、两个公式也是统计一样的值，一个返回 1，另一个返回 3，说明逻辑值在单元格时，Count函数不把它们计入统计个数，而在数组时把它们计入统计个数。

　　（五）Value 为空单元格、空值和错误值的实例

　　1、双击 B1 单元格，把公式 =COUNT(A1:A4) 复制到 B1，按回车，返回统计结果 0；双击 A1，里面什么都没有，说明它为空单元格；再双击 A2，里面有一个返回空值 If 公式，说明空值也被Count函数忽略；操作过程步骤，如图5所示：

图5

　　2、从操作中可以看出，Count函数忽略空单元格、空值和错误值。

　　三、Excel Count函数的扩展使用实例

　　（一）If + Count函数组合统计满足指定条件的个数

　　1、假如要统计销量大于 2000 的水果销量个数。双击 D8 单元格，把公式 =COUNT(IF(D2:D7>2000,D2:D7,"")) 复制到 D8，按回车，返回统计结果 3；操作过程步骤，如图6所示：

图6

　　2、公式 =COUNT(IF(D2:D7>2000,D2:D7,"")) 说明：

　　A、公式为数组公式，因此要按 Ctrl + Shift + 回车。

　　B、D2:D7>2000 为 If 的条件，D2:D7 以数组的形式返回 D2 至 D7 中的值，然后逐一取出每个元素与 2000 比较，如果大于 2000 返回 True，否则返回 False；例如：第一次取出 685，由于不大于 2000，所以返回 False；第二次取出 3500，由于大于 2000，所以返回 True，其它的以此类推；最后返回 {FALSE;TRUE;FALSE;TRUE;FALSE;TRUE}。

　　C、则 IF(D2:D7>2000,D2:D7,"") 变为 IF({FALSE;TRUE;FALSE;TRUE;FALSE;TRUE},D2:D7,"")，接着，取数组中的第一个元素 FALSE，由于为假，所以返回 ""；第二次取出数组的第二个元素 TRUE，由于为真，所以返回 D2:D7 与数组对应的元素 D3；其它的以此类推；最后返回{"";3500;"";2050;"";2200}。

　　D、则公式变为 =COUNT({"";3500;"";2050;"";2200})，最后用 Count 统计数组中数值的个数，因此结果为 3。

　　（二）Count + Find函数组合统计重复值的个数

　　1、假如要统计水果表中“分类”列“浆果”的个数。双击 B8 单元格，把公式 =COUNT(FIND("浆果",B2:B7)) 复制到 B8，按 Ctrl + Shift + 回车，返回统计结果 3，操作过程步骤，如图7所示：

图7

　　2、公式 =COUNT(FIND("浆果",B2:B7)) 说明：

　　A、FIND("浆果",B2:B7) 用于在 B2:B7 中找出所有“浆果”，如果为“浆果”返回 1，否则返回值错误 #VALUE!，最后返回数组{1;#VALUE!;1;#VALUE!;1;#VALUE!}。

　　B、则公式变为 =COUNT({1;#VALUE!;1;#VALUE!;1;#VALUE!})，最后对数组进行统计，由于错误值不统计，只统计数值，因此统计结果为 3。

　　（三）Count + Frequency函数组合统计不重复的数值个数

　　1、假如要统计价格不包含重复的个数。双击 C8 单元格，把公式 =COUNT(0/(FREQUENCY(C2:C7,C2:C7))) 复制到 C8，按回车，返回统计结果 5，操作过程步骤，如图8所示：

图8

　　2、公式 =COUNT(0/(FREQUENCY(C2:C7,C2:C7))) 说明：

　　A、FREQUENCY(C2:C7,C2:C7) 用于统计 C2:C7 每个数值的出现频率；执行时，第一次取出第二个参数中的 C2（即 5），然后在 C2:C7 中统计小于等于 5 且大于 3.5 的数值个数（结果为 2），因为直接把 C2:C7 作为 Frequency函数的 Bins_Array 参数（即对要统计的数值划分区间参数），而比 5 小的值是 3.5，因此 3.5 与 5 为一个区间；第二次取出第二个参数中的 C3（即 3），同样在 C2:C7 中统计小于等于 3 且大于 2.5 的数值个数（结果为 1）；第三次取出 5，由于 5 已经统计过不再计入统计，因此结果为 0；其它的以此类推，最后返回数组 {2;1;0;1;1;1;0}。

　　B、则 0/(FREQUENCY(C2:C7,C2:C7) 变为 0/{2;1;0;1;1;1;0}，接着用 0 除以数组中的每个数，结果为 {0;0;#DIV/0!;0;0;0;#DIV/0!}；用 0 除以数组中的每个值主要是把数组中的 0 过滤掉，即把统计过的和没有的值过滤掉。

　　C、则公式变为 =COUNT({0;0;#DIV/0!;0;0;0;#DIV/0!})，最后对数组中的数值进行统计，总共有 5 个 0，两个除数为 0 错误 #DIV/0!，因此统计结果为 5。

版权声明：本文内容由网络用户投稿，版权归原作者所有，本站不拥有其著作权，亦不承担相应法律责任。如果您发现本站中有涉嫌抄袭或描述失实的内容，请联系我们jiasou666@gmail.com 处理，核实后本网站将在24小时内删除侵权内容。