Excel Left函数和LeftB函数使用方法的9个实例，含倒数提取、数值带单位求和及与If、Find组合

在 Excel 中，Left函数用于从文本中提取从左边第一个字符开始的指定字符数，而LeftB函数用于从文本中提取从左边第一个字符开始的指定字节数；它们的区别为：前者提取字符数，即把全角和半角都计作一个字符；后者提取字节数，即把全角计作两个字节、半角计作一个字节。

在实际应用中，Left函数和LeftB函数常与 If、Len、LenB、Find、Sum、Value 和 Match 等函数组合使用，例如 Left + Len（或 LeftB + LenB）组合实现倒数提取字符，If + Find 组合实现返回符合条件的查找内容，Left + Find 组合实现自动计算要提取的字符数，Sum + Value + Left 组合实现数值带单位求和。

一、Excel Left函数和LeftB函数的语法

1、Left函数表达式：LEFT(Text, [Num_Chars])

中文表达式：LEFT(文本, 提取字符数)

2、LeftB函数表达式：LEFTB(Text, [Num_Bytes])

中文表达式：LEFTB(文本, 提取字节数)

3、说明：

A、Left函数把全角（如汉字）和半角字符（如数字与字母）都计作一个字符，LeftB函数把全角字符计作两个字节、半角字符计作一个字节。

B、Num_Chars 为要提取字符数，它必须大于或等于 0，否则将返回值错误 #VALUE!；如果 Num_Chars 大于文本长度，将返回所有文本；如果省略 Num_Chars，则默认取 1。

C、Num_Bytes 为要提取字符的字节数，它必须大于或等于 0，否则也将返回值错误 #VALUE!；如果 Num_Bytes 大于文本长度的一倍或两倍（半角字符大于一倍，全角字符大于两倍），将返回所有文本；如果省略 Num_Bytes，则默认取 1。

二、Excel Left函数的使用方法及实例

（一）提取左边的数字实例

1、假如要提取单位左边的数字。双击 B1 单元格，输入公式 =LEFT(A1,3)，按回车，返回 2.5；选中 B1，把鼠标移到 B1 右下角的单元格填充柄上，鼠标变为加号后，双击左键，则返回剩余单位前的数字；操作过程步骤，如图1所示：

图1

2、公式 =LEFT(A1,3) 中，A1 为要提取数字的文本，3 为提取字符数；公式的意思是，把 A1 中的“2.5升/瓶”从第一个字符开始提取且只提取 3 个字符。

（二）提取一个字符和所有文本的实例

1、双击 A8 单元格，输入公式 =LEFT(A3,)，按回车，返回“空”；双击 A8，把逗号去掉，按回车，返回“青”字；再次双击 A8，在 A3 后输入“,6”，按回车，返回“青皮西瓜”；操作过程步骤，如图2所示：

图2

2、公式说明：

A、公式 =LEFT(A3,) 返回空，而公式 =LEFT(A3) 返回“青”，说明省略提取字符数参数时，不能有逗号；另外，省略“提取字符数”时，它的值默认取 1。

B、公式 =LEFT(A3,6) 从第一个字符开始返回 6 个字符，由于 A3 中只有 4 个字符，因此只返回到文本末尾，即返回所有字符。

（三）提取字符数小于 0，返回 #VALUE! 错误实例

1、双击 B1 单元格，把公式 =LEFT(A1,-1) 复制到 B1，按回车，返回值错误 #VALUE!；双击 B1，把 -1 改为 1，按回车，返回 2；再次双击 B1，把 1 改为 0，按回车，返回“空”；操作过程步骤，如图3所示：

图3

2、公式 =LEFT(A1,-1) 返回错误，是因为第二个参数“提取字符数”必须大于等于 0；公式 =LEFT(A1,1) 返回 A1 中的第一个字符 2；公式 =LEFT(A1,0) 由于“提取字符数”为 0，因此返回“空”。

三、Excel LeftB函数的使用方法及实例

（一）提取数字和字母的实例

1、假如要从 A 列中提取重量和单位。双击 B1 单元格，输入公式 =LEFTB(A1,3)，按回车，返回 3Kg；把鼠标移到 B1 右下角的单元格填充柄上，然后双击，提取出剩余单元格的重量和单位；操作过程步骤，如图4所示：

图4

2、公式 =LEFTB(A1,3) 中，A1 为要提取字符的文本，3 为要提取的字节数；公式的意思是，从 A1 中的“3Kg苹果”中第一个字符开始提取 3 个字节，即提取 3Kg；从返回结果可知，LeftB函数与Left函数一样，都把数字和字母计作一个字节。

（二）提取汉字的实例

1、假如要从“苹果12￥/Kg”中提取“苹果”二字。双击 B1 单元格，把公式 =LEFTB(A1,4) 复制到 B1，按回车，返回提取结果“苹果”；双击 B1，把 4 改为 3，按回车，只返回“苹”字；操作过程步骤，如图5所示：

图5

2、公式 =LEFTB(A1,4) 从 A1 中提取 4 个字节，返回结果只有“苹果”二字，说明 LeftB 把每个汉字计作两个字节；则公式 =LEFTB(A1,3) 只返回“苹”一字，说明提取汉字时，单个字节被忽略，因为一个字节不能组成一个汉字。

四、Excel Left函数和LeftB函数的应用实例

（一）Left + Len函数组合实现倒数提取字符

1、假如要从倒数第 5 位开始提取。双击 B2 单元格，把公式 =LEFT(A2,LEN(A2)-5 + 1) 复制到 B2，按回车，返回 A2018；操作过程步骤，如图6所示：

图6

2、公式 =LEFT(A2,LEN(A2)-5 + 1) 说明：

A、公式中的 5 为倒数提取的开始位置，即从右往左第 5 个字符开始提取；LEN(A2) 用于返回 A2 的字符数，结果为 9，Len函数把无论是全角字符还是半角字符都计作一个字符。

B、则公式变为 =LEFT(A2,9 - 5 + 1)，进一步计算变为 =LEFT(A2,5)，即从左边开始提取，共提取 5 个字符，结果为 A2018。

提示：LeftB + LenB 也可以实现同样功能，公式可以这样写：=LEFTB(A2,LENB(A2)-5 + 1)，把公式复制到 B3，按回车，也返回 A2018，操作过程步骤，如图7所示：

图7

公式 =LEFTB(A2,LENB(A2)-5 + 1) 中，5 也为倒数提取字符开始的位置，LENB(A2) 返回 A2 的字节数，结果为 9，LenB函数把全角字符计作 2 个字节、半角字符计作 1 个字节，这与 LeftB 相同；则公式变为 =LEFTB(A2,5)，然后从左边提取 5 个字节的字符。

（二）If + Left函数组合实现返回符合条件的查找内容

1、假如要找出所有“黄”姓员工的“职务”。双击 D2 单元格，把公式 =IF(LEFT(A2)="黄",C2,"") 复制到 D2，按回车，返回空值；选中 D2，用双击单元格填充柄的方法找出剩余员工的职务；操作过程步骤，如图8所示：

图8

2、公式 =IF(LEFT(A2)="黄",C2,"") 说明：

A、LEFT(A2) 用于截取 A2 中姓名中的“姓”；LEFT(A2)="黄" 是 If 的条件，如果 LEFT(A2) 返回结果等于“黄”，则返回 C2，否则返回空值。

B、当公式在 D2 时，LEFT(A2) 返回“李”，不等于“黄”，所以返回空值；当公式在 D5 时，A2 自动变 A5， LEFT(A5) 返回“黄”，所以返回 C5（即“经理”）。

（三）Left + Find函数组合实现自动计算要提取字符数

1、当要从比较多的文本中提取字符或仅提取到特定字符，可以先用Find函数返回某个字符的位置，再用Left函数提取。假如要提取 A2 中从开始字符到 5 的这一串字符。双击 B2 单元格，把公式 =LEFT(A2,FIND(5,A2)) 复制到 B2，按回车，返回 A201809010005；操作过程步骤，如图9所示：

图9

2、公式 =LEFT(A2,FIND(5,A2)) 说明：

A、FIND(5,A2) 用于返回 5 在 A2 中的位置（结果返回 13），5 为查找文本，A2 为找查 5 的原文本，FIND(5,A2) 省略了最后一个指定查找开始位置的参数，默认从第一个字符开始查找。

B、则公式变为 =LEFT(A2,13)，最后从左边第一个字符开始截取 13 字符，即截取得 A201809010005。

（四）Sum + Value + Left函数组合实现数字带单位的求和

1、如果求和的数值后面带单位，则无法用Sum函数求和，需要先把数值提取出来再求和。假如要求一个水果表的销量之和。双击 D8 单元格，把公式 =SUM(VALUE(LEFT(D2:D7,4))) 复制到 D8，按 Ctrl + Shift + 回车，返回求和结果 12743；操作过程步骤，如图10所示：

图10

2、公式 =SUM(VALUE(LEFT(D2:D7,4))) 说明：

A、公式为数组公式，所以要按 Ctrl + Shift + 回车。D2:D7 以数组形式返回 D2 至 D7 中的值，即{"2685kg";"3500kg";"1258kg";"2050kg";"1050kg";"2200kg"}

B、则 LEFT(D2:D7,4) 变为 则 LEFT({"2685kg";"3500kg";"1258kg";"2050kg";"1050kg";"2200kg"},4)，执行时，第一次取出数组中的第一个元素 "2685kg"，并取截取前四位数字，即 2685；第二次取出数组中的第二个元素，也截取前四位数字，即 3500；其它的以此类推，最后返回 {"2685";"3500";"1258";"2050";"1050";"2200"}。

C、则公式变为 =SUM(VALUE({"2685";"3500";"1258";"2050";"1050";"2200"}))，进一步计算，用Value函数把数组中字符元素转为数值，则公式变为 =SUM({2685;3500;1258;2050;1050;2200})，最后用Sum函数求和。

版权声明：本文内容由网络用户投稿，版权归原作者所有，本站不拥有其著作权，亦不承担相应法律责任。如果您发现本站中有涉嫌抄袭或描述失实的内容，请联系我们jiasou666@gmail.com 处理，核实后本网站将在24小时内删除侵权内容。