Excel标准差计算的6个函数的用法及区别，含用Stdev/Stdev.S/StdevA/StdevP等求样本与总体标准差（含带条件

标准差分为样本标准差和总体标准差，前者是指从一组数据中抽取一些数据作为样本计算标准差，后者是指把所有数据都计算标准差，而在现实中取得所有数据常常不可能，所以一般都是计算样本标准差。Excel标准差计算的函数共有 6 个，实际上只有 4 个，因为有两个新增的只是用于取代旧函数，它们与旧函数作用一样。其中计算样本标准差的有 Stdev、Stdev.S、StdevA，计算总体标准差的有 StdevP、Stdev.P、StdevPA。

计算标准差除计算一组数值的外，还可以计算满足两个或多个条件的标准差。另外，还可以把计算标准差函数与 OffSet、Match 函数组合实现添加数据后自动计算标准差和计算最近几天的标准差。

一、Excel标准差的计算函数

（一）样本标准差的计算函数

1、表达式

Stdev函数表达式：STDEV(Number1,[Number2],...)

Stdev.S函数表达式：STDEV.S(Number1,[Number2],...)

StdevA函数表达式：STDEVA(Value1, [Value2], ...)

2、说明：

A、Stdev函数与Stdev.S函数都用于计算数值的样本标准差，它们至少要用一个参数，最多只能 255 个参数；Stdev.S函数是 Excel 2010 新增的，用于取代Stdev函数，在以后的 Excel 版本中，Stdev函数可能不会再支持。

B、StdevA函数除用于计算数值的样本标准差外，还用于计算逻辑（True 或 False）和文本数值的样本标准差；它也至少要有一个 Value、最多只能有 255 个 Value。

C、Stdev函数（Stdev.S函数）与StdevA函数的区别：它们的区别仅限于如何处理逻辑值与文本数值，对于逻辑值和文本数值，如果直接输入到参数列表中，Stdev函数计入计算标准差，True 被转为 1、False 被转为 0；如果是在数组或引用单元格中，Stdev函数把它们忽略。而StdevA函数，无论把逻辑值与文本数值输入到哪里都把它们计入计算标准差。另外，如果参数列表中有无法转为数值的文本，它们都返回错误；如果数组或引用单元要格有无法转为数值的文本，它们都忽略。

（二）总体标准差的计算函数

1、表达式

StdevP函数表达式：STDEVP(Number1,[Number2],...)

Stdev.P函数表达式：STDEV.P(Number1,[Number2],...)

StdevPA函数表达式：STDEVPA(Value1, [Value2], ...)

2、说明：

A、StdevP函数与Stdev.P函数作用也一样都用于计算数值的总体标准差，它们至少要用一个参数，最多只能 255 个参数；Stdev.P函数也是 Excel 2010 新增的，用于取代StdevP函数，在以后的 Excel 版本中，StdevP函数可能被放弃。

B、StdevPA函数除用于计算数值的总体标准差外，还用于计算逻辑（True 或 False）和文本数值的总体标准差；它也至少要有一个 Value、最多只能有 255 个 Value。

C、StdevP函数（Stdev.P函数）与StdevPA函数的区别：它们的区别同样仅限于怎么处理逻辑值与文本数值，对于逻辑值和文本数值，如果直接输入到参数列表中，StdevP函数计入计算标准差，True 被转为 1、False 被转为 0；如果是在数组或引用单元格中，StdevP函数将它们忽略。而StdevPA函数，无论把逻辑值与文本数值输入到哪里都把它们计入计算标准差。另外，如果参数列表中有无法转为数值的文本，它们也都返回错误；如果数组或引用单元格有无法转为数值的文本，它们也都忽略。

二、Excel标准差（样本）计算函数的使用方法及实例

（一）用 Stdev（Stdev.S）计算数值的标准差

（1）用 Stdev 与 Stdev.S 计算的实例

1、假如要计算英语成绩的样本标准差。双击 B2 单元格，把公式 =STDEV(B2:B29) 复制到 B2，按回车，返回 7.494883616；双击 B3，把公式 =STDEV.S(B2:B29) 复制到 B3，按回车，也返回 7.494883616；框选 B2:B3，当前选项卡为“开始”，单击“常规”右边的黑色小倒三角，在弹出的选项中选择“数字”，则标准差保留两位小数；操作过程步骤，如图1所示：

图1

2、公式说明：

A、B2:B29 为计算标准差的引用单元格，两个公式返回的结果一致，说明 Stdev 与 Stdev.S 作用一样。

B、公式返回的结果默认保留多位小数，演示中只设置了保留两位小数，如果要保留其它小数位数，可按 Ctrl + 1（需要关闭中文输入法），打开“设置单元格格式”窗口，选择“数字”选项卡，再选择左边的“数值”，然后在右边的“小数位数”输入具体的数值，单击“确定”即可。

（2）True 与 False 计入与忽略的实例

1、True 与 False 计入计算标准差

A、双击 A1 单元格，把公式 =STDEV(24,27) 复制到 A1，按回车，返回 2.121320344；双击 A2，把公式 =STDEV(24,27,TRUE) 复制到 A2，按回车，返回 14.2243922；双击 A3，把公式 =STDEV(24,27,FALSE) 复制到 A3，按回车，返回 14.79864859；操作过程步骤，如图2所示：

图2

B、公式说明：

公式 =STDEV(24,27,TRUE) 和 =STDEV(24,27,FALSE) 返回的结果与 =STDEV(24,27) 不一样，说明 TRUE 和 FALSE 都计入了计算标准差，由此可知，逻辑值直接写到Stdev函数的参数列表中被计入求标准差。

2、True 与 False 计算标准差时被忽略

A、双击 C2 单元格，把公式 =STDEV(B2:B3) 复制到 C2，按回车，返回 2.121320344；双击 C3，把同一公式复制到 C3，把公式改为 =STDEV(B2:B4)，按回车，也返回 2.121320344；选中 B4，把 TRUE 改为 false，单击 C3，C3 中的值未变；双击 C6，把公式 =STDEV({24,27,TRUE,FALSE}) 复制到 C6，按回车，同样返回 2.121320344；操作过程步骤，如图3所示：

图3

B、公式说明：

从演示中可知，不管是否包含 True 或 False，每个公式都返回一样的结果，说明 True 和 False 在单元格或数组中时，Stdev函数都把它们忽略。

（3）有能转为数值的文本计入与忽略的实例

1、双击 A1 单元格，把公式 =STDEV(2.58,2.39,"2.67") 复制到 A1，按回车，返回 0.142945211，双击 A1，把“,"2.67"”删除，按回车，返回 0.134350288；双击 A2，把公式 =STDEV(B1:B3) 复制到 A2，按回车，返回 0.134350288；操作过程步骤，如图4所示：

图4

2、公式说明：

公式 =STDEV(2.58,2.39,"2.67") 与 =STDEV(2.58,2.39) 返回的结果不一样，说明，数值文本 "2.67" 计入了计算标准差；而公式=STDEV(B1:B3) 与 =STDEV(2.58,2.39) 的结果一样，说明 B3 中的 2.67 没有计入计算标准差，因为它是文本。

（4）有无法转为数值的文本返回错误与忽略的实例

1、双击 A1 单元格，把公式 =STDEV(2.58,2.39,"十") 复制到 A1，按回车，返回值错误 #VALUE!；双击 A2，把公式 =STDEV(B1:B3) 复制到 A2，按回车，返回 0.134350288；操作过程步骤，如图5所示：

图5

2、公式说明：

两个公式计算的是同样数值和文本的标准差，公式 =STDEV(2.58,2.39,"十") 返回错误，说明，无法转为数值的文本不能写到参数列表中；而公式 =STDEV(B1:B3) 能返回正确的值，说明数组或引用单元格有无法转为数值的文本，这些文本被忽略而不影响计算。

（二）用 StdevA 计算数值、文本数值和逻辑值的标准差

（1）引用单元格有数值、文本数值和逻辑值的实例

1、双击 B2 单元格，把公式 =STDEVA(A2:A6) 复制到 B2，按回车，返回 47.00850987；选中 A4，把 86 删除，B2 中的值变为49.47305664，选中 A5，把 True 删除，B2 中的值变为 49.81298358，再把 A6 中的 False 删除，B2 中的值变为 5.656854249；操作过程步骤，如图6所示：

图6

2、公式说明：

A2 和 A3 中的数值为数值型，A4 中的数值为文本型，当把 A4 中的数值删除后，标准差结果由 47.00850987 变为 49.47305664，说明StdevA函数把单元格中的文本计入计算标准差；当依次把 True 和 False 删除后，标准差结果也发生变化，说明StdevA函数把逻辑值记入求标准差。

（2）StdevA 与 Stdev 对文本数值计入与忽略比较实例

1、StdevA 对于文本数值，无论是直接写到参数列表还是写到单元格，都把它计入求标准差，但对于小数的处理不一样。如 E3、E4、E5 中的计算结果不一样，说明 StdevA 把文本数值计入了求标准差；当把 "2.67" 直接写到参数列表时，文本型 "2.67" 被转为数值 2.67，而单元格中的 2.67 为文本时，它先被取代小数点后再转为数值，转为数值后的结果为 267，这一点可以从把 C5 中的 2.67 改为 267 后 E5 中的结果不变得到证实，演示如图7所示：

图7

2、StdevA 与 Stdev 对文本数值的区别为：Stdev 仅对直接写到参数列表中的文本数值 "2.67" 计入求标准差，StdevA 对参数列表和单元格中的文本数值 "2.67" 都计入求标准差。图7中，颜色相同的计算结果相同，即对文本数值的处理方式相同。

三、Excel标准差（总体）计算函数的使用方法及实例

（一）用 StdevP 与 Stdev.P 计算总体标准差的实例

1、双击 B2 单元格，把公式 =STDEVP(A2:A6) 复制到 B2，按回车，返回 0.681791757；双击 B3，把同一公式复制到 B3，再在 P 前加一点，公式变为 =STDEV.P(A2:A6)，按回车，返回一样的结果；操作过程步骤，如图8所示：

图8

　2、公式说明：

公式 =STDEVP(A2:A6) 与 =STDEV.P(A2:A6) 返回一样的结果，说明它们作用一样都用于计算数值的总体标准差。

（二）用 StdevPA 计算包含数值、文本数值和逻辑值的总体标准差实例

1、双击 B2 单元格，把公式 =STDEVPA(A2:A6) 复制到 B2，按回车，返回 3.851360279；选中 A4，把文本数值 8.16 删除，B2 中的值变为 3.846526842；把 A5 中的 False 删除，B2 中的值变为 3.377049995；再把 A6 中的 True 删除，B2 中的值变为 0.205；操作过程步骤，如图9所示：

图9

2、公式说明：

当把 A4 中的文本数值删除后，标准差结果有变化，说明StdevPA函数把文本数值计入求标准差；再把 True 和 False 删除，标准差结果也有变化，说明StdevPA函数也把逻辑值计入求标准差。

提示：StdevP函数与StdevPA函数对数值文本、逻辑值和无法转为数值的文本的处理区别，请参考Stdev函数与StdevA函数的区别。

四、Excel标准差计算函数的应用实例

（一）计算满足两个条件的样本标准差

1、假如要计算“毛衣”在上海销量的样本标准差。双击 D12 单元格，把公式 =STDEV((B2:B11="毛衣")*(C2:C11="上海")*(D2:D11)) 复制到 D12，按 Ctrl + Shift + 回车，返回结果 456.5364；操作过程步骤，如图10所示：

图10

2、公式 =STDEV((B2:B11="毛衣")*(C2:C11="上海")*(D2:D11)) 说明：

A、B2:B11="毛衣" 为公式的第一个条件，意思是：在 B2:B11 中查找为“毛衣”的服装，如果为“毛衣”，返回 True，否则返回 False。执行时，第一次从 B2:B11 中取出 B2，由于 B2 为“羽绒服”，因此返回 False；第二次从 B2:B11 中取出 B3，由于 B3 为“休闲西服”，也返回 False；其它的以此类推，最后返回数组 {FALSE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE}。

B、C2:C11="上海" 为公式的第二个条件，意思是：在 C2:C11 中查找为“上海”的“地区”，如果为“上海”，返回 True，否则返回False，最后返回数组 {TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}。

C、则 (B2:B11="毛衣")*(C2:C11="上海") 变为 {FALSE;FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE}*{TRUE;FALSE;TRUE;TRUE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}，接着，取第一个数组的第一个元素与第二个数组的第一个元素相乘，结果为0（因为 True 被转为 1，False 被转为 0）；第二次取第一个数组的第二个元素与第二个数组的第二元素相乘，结果为 0；其它的以此类推，最后返回数组 {0;0;0;1;0;1;0;0;0;0}。

D、D2:D11 以数组返回 D2 到 D11 中的数值，即返回 {763;692;1090;969;583;1286;990;686;960;986}。

E、则公式变为 =STDEV({0;0;0;1;0;1;0;0;0;0}*{763;692;1090;969;583;1286;990;686;960;986})，接着，把两数组对应元素相乘，则公式进一步变为 =STDEV({0;0;0;969;0;1286;0;0;0;0})，最后用 Stdev 求样本标准差。

提示：以上是计算满足两个条件的样本标准差，如果要计算满足三个或更多个条件的样本标准差，可以在公式的第二个 * 后继续加条件。另外，如果要计算总体标准差，把 Stdev 改为 StdevP 即可。

（二）Stdev + OffSet + Match 组合实现添加新数据后自动计算标准差和计算最近几天的标准差

（1）计算所有数据的样本标准差

1、假如要求每添加一行“指数”自动计算指数的样本标准差。双击 C3 单元格，把公式 =STDEV(OFFSET(B1,1,,MATCH(9E+307,B:B)-1)) 复制到 C3，按回车，返回结果 71.0624；选中 A8，输入“7日”，按 Tab 键把光标移到 B8，输入 837，按回车，C3 中的值自动变为64.9300，说明添加一行后自动重新计算了包含新添加数据的标准差；继续在 A9 和 B9 输入数据，按回车，C3 的值又自动变为 68.3013；操作过程步骤，如图11所示：

图11

2、公式 =STDEV(OFFSET(B1,1,,MATCH(9E+307,B:B)-1)) 说明：

A、9E+307 是 Excel 允许输入的最大值，这里用于表示最后一行。MATCH(9E+307,B:B) 用于在 B 列返回最后一行的位置，当表格只有 7 行时，它返回 7；Match 省略了最后一个参数，默认取 1，因为第二个参数 B:B 后无逗号，意思是：在 B 列查找小于等于 9E+307 的最大值并返回它所在 B 列的位置。

B、则 OFFSET(B1,1,,MATCH(9E+307,B:B)-1) 变为 OFFSET(B1,1,,7-1)，接着，以 B1 为基准，返回 B1 下 1 行 0 列且高度为 6 宽度为1 的单元格引用，即返回 $B$2:$B$7。OffSet 函数省略了第三个参数列号，默认取 0；还省略了第五个参数宽度，默认取与 B1 一样的宽度，即取 1。

C、则公式变为 =STDEV($B$2:$B$7)，最后对 B2:B7 中所有数值计算样本标准差。

D、当在表格后添加一行后，MATCH(9E+307,B:B) 返回 8，OFFSET(B1,1,,8-1) 返回 $B$2:$B$8，恰好包含了新增加的行，因此添加新数据后会自动把新数据计入求标准差。

（2）计算最近 7 天的样本标准差

1、双击 D3 单元格，把公式 =STDEV(OFFSET(B1,MATCH(9E+307,B:B)-1,,-7)) 复制到 D3，按回车，返回结果 58.5800；操作过程步骤，如图12所示：

图12

2、公式 =STDEV(OFFSET(B1,MATCH(9E+307,B:B)-1,,-7)) 说明：

A、MATCH(9E+307,B:B) 也用于在 B 列返回表格最后一行的位置，结果为 9。

B、则 OFFSET(B1,MATCH(9E+307,B:B)-1,,-7) 变为 OFFSET(B1,9-1,,-7)，接着，也以 B1 为基准，返回 B1 下 8 行 0 列且高度为 -7 宽度为 1 的单元格引用，即返回 $B$3:$B$9。B1 下 8 行即到了 B9，-7 是指从下往上，在这里的意思是：从 B9 往上 7 行，即 B3。

C、则公式变为 =STDEV($B$3:$B$9)，最后对 B3:B9 中的数值计算样本标准差，即实现计算最近 7 天的标准差。如果要计算 5 天或 14 天，把 -7 改为 -5 或 -14 即可。

版权声明：本文内容由网络用户投稿，版权归原作者所有，本站不拥有其著作权，亦不承担相应法律责任。如果您发现本站中有涉嫌抄袭或描述失实的内容，请联系我们jiasou666@gmail.com 处理，核实后本网站将在24小时内删除侵权内容。